Problem:

Customer created an ASP.NET Web Application using Visual COBOL 2.1 for Visual Studio 2010. The application runs fine in development but when he deploys it to an IIS Server under Windows Server 2012, on which COBOL Server is installed, when he runs the web site he gets the error:

Method not found:  MFClrRts.MFClrRts.Disconnect Context(Int16 ByRef)

Why?

Resolution:

The problem is that the version of COBOL Server that was installed on the production computer was COBOL Server for Visual Studio 2012 and the application was developed with Visual COBOL for Visual Studio 2010.

The two products are not compatible.

If you develop your application using the Visual COBOL for Visual Studio 2010 product then you must deploy it to a system on which the COBOL Server for Visual Studio 2010 product is installed.

If you develop using the Visual COBOL for Visual Studio 2012 product then you must deploy it to a system on which the COBOL Server for Visual Studio 2012 product is installed.

In this case the customer rebuilt the application with Visual COBOL for Visual Studio 2012 an then redeployed it and everything worked fine.

Problem:

Customer has a .NET managed code solution in which he has two projects.
The first project is a main console application that generates an assembly called mainprog.exe.

The second project is a Class Library project that generates an assembly called subprog.dll.
Within the subprog project is a program called prog2.cbl.

mainprog.cbl calls this prog2 through the use of:

   call "prog2" using ...

Because prog2 is not the name of the .dll on disk, the .dll needs to be loaded in order to make the entry point prog2 available to mainprog.

The customer has created an app.config file for the mainprog project which contains the following preload section which will cause the program to load the subprog.dll when it starts:

 <MicroFocus.COBOL.Application>
    <Switches></Switches>
    <Environment></Environment>
    <Interop>
       <PreLoad>
         <add key="subprog.dll" value="managed" />
       </PreLoad>
    </Interop>
</MicroFocus.COBOL.Application>

When he runs this in development it works fine and the program prog2 is found without a problem.

When he moves the program to a production computer on which COBOL Server is installed, when he runs the program he gets a RTS error 173 that prog2 program name cannot be found.

Why?

Resolution

It turns out that although the customer moved the mainprog.exe and subprog.dll to the production computer he did not move the mainprog.exe.config file which is automatically generated by Visual COBOL in the project output folder.

Since this file actually contains the required statement to preload the subprog.dll and it was missing, the subprog.dll was not loaded and thus the prog2 entry point could not be found.

Copying the .config file to the production system solved this problem.

Problem

The following error occurs when attempting to start ESQLCONFIGW.EXE in Visual COBOL 2.1 or Visual COBOL 2.1 Update 1:

Unhandled exception has occurred in your application. If you click Continue, the application will ignore this error and attempt to continue. If you click Quit, the application will close immediately.

Object reference not set to an instance of an object.

Resolution

This is a known issue, and it has been addressed in Visual COBOL 2.2.

To work around the problem in Visual COBOL 2.1, the equivalent command line esqlconfig.exe can be used from Start > Programs > Micro Focus Visual COBOL for Visual Studio 20xx > Tools > Visual COBOL 20xx Command Prompt where xx is either 10 or 12.

When running esqlconfig with no parameters or an invalid parameter, it displays the current default setting and appropriate syntax.

Problem:

Customer is trying to define an ISAM file within a class program within an ASP.NET Web Application.
The compiler is flagging an error that points to the file status data-item that is defined in the select clause.

The error is as follows:

COBCH1268 : A static file cannot reference instance items …\Default.aspx.cbl

The program is shown below:

       class-id mywebsite_Default is partial   
              inherits type System.Web.UI.Page public.
       input-output section.
       file-control.
            select test-file assign to "C:\TEST.DAT"
                                   organization is indexed
                                    access is dynamic
                                    record key is test-refno
                                    file status is FS.
       data division.
       file section.
       fd test-file is external.
       01 test-record.
          03 test-refno            pic 9(8).
          03 test-name            pic x(20).
       working-storage section.
       77 FS                         pic x(2).   
       method-id Page_Load protected.
       local-storage section.
       procedure division using by value sender as object by value e as type EventArgs.

          goback.         

       end method.
       end class.

Resolution:

This error occurs because you have your file defined as EXTERNAL in your FD.

When you define a file as external then the compiler will automatically generate the file as being static so that it is accessible to all instances of the class.

This means that the file status data item defined for the file needs to also be defined as static.

You can do this as follows:

77 FS   PIC X(2) STATIC.

The alternative would be to remove the external clause from the file description and then the file would belong to the instance and not to the class and you would not have to define the file status as static.

Problem:

Customer is converting from ACUCOBOL to Visual COBOL managed .NET and they are receiving a compiler error on a program that is doing embedded SQL access.

They have host variables defined as PIC X(5) COMP-X.

Are these allowed in Visual COBOL?

Resolution:

In Visual COBOL when using OpenESQL these host variables would need to be defined as PIC X(4) COMP-X/COMP-5 for integer columns or PIC X(8) COMP-X/ COMP-5 for bigint columns.

There is a chart that shows compatible COBOL data types for host variables here:

There’s further detail on all the host variable definitions supported by OpenESQL – as well as the DB2 ECM– under here .

Problem:

Customer is developing a Windows Forms application and would like it to display a LoginForm to do user authentication and then to exit the application if it fails or continue on and display the main form if successful.

How can this be done?

Resolution:

Change the main.cbl program to display the loginform first and then start the application with the main form depending on the results of the login.

Example:

main.cbl

       class-id winformlogin.Main.
       method-id Main static
           attribute System.STAThread.
       local-storage section.
       01 mainForm type winformlogin.Form1.
       01 loginForm type winformlogin.LoginForm1.
       01 myresult  type DialogResult.
       procedure division.
       
           set loginForm to new winformlogin.LoginForm1
           set myresult to loginForm::ShowDialog
           if myresult = type DialogResult::OK
              set mainForm to new winformlogin.Form1()
              invoke type System.Windows.Forms.Application::EnableVisualStyles()
              invoke type System.Windows.Forms.Application::Run(mainForm)
           else
              invoke type System.Windows.Forms.Application::Exit
           end-if
           goback.
       
       end method.
       end class.

LoginForm1.cbl

       class-id winformlogin.LoginForm1 is partial
                 inherits type System.Windows.Forms.Form.

       working-storage section.
 
       method-id NEW.
       procedure division.
           invoke self::InitializeComponent()
           goback.
       end method.

       method-id btnOK_Click final private.
       procedure division using by value sender as object 
                                         e as type System.EventArgs.
           set self::DialogResult to type DialogResult::OK
           invoke self::Close()
           goback.
       end method.

       method-id btnCancel_Click final private.
       procedure division using by value sender as object
                                         e as type System.EventArgs.
           set self::DialogResult to type DialogResult::Cancel
           invoke self::Close()
           goback.
       end method.

       end class.

Problem:

Customer has a Windows Forms application which uses a MaskedTextBox control.
When the control is entered using the Tab key there is no problem as the cursor will be in the starting position.
If a user instead clicks in the center of the control the cursor remains in the center of the control.

Customer asks: Is there a way to force the cursor to the right or left edge of a MaskedTextBox? I want the insertion point to always be on the right for numeric data and on the left for text.

Resolution:

You could do something like the following in the MouseUp event for the MaskedTextbox control:

       method-id maskedTextBox1_MouseUp final private.
       procedure division using by value sender as object e as type System.Windows.Forms.MouseEventArgs.

         invoke type SendKeys::Send("{HOME}")

       end method.

If your control's RightToLeft property is set to Yes then this will position the cursor to the rightmost position.

If RightToLeft is set to No then it will position the cursor on the leftmost position.

You could also use the MouseClick event and use the following:

          set maskedTextBox1::SelectionStart to 0

Problem:

Customer is developing a WPF application and would like to display a Windows Message Box that has a Yes and No button. How can the application tell which one of these buttons was pressed after returning?

The Message Box is being displayed as follows:

    invoke type System.Windows.MessageBox::Show("My Text", "My Caption",
         type System.Windows.MessageBoxButton::YesNo,
         type System.Windows.MessageBoxImage::Question,
         type System.Windows.MessageBoxResult::Yes,
         type System.Windows.MessageBoxOptions::RightAlign)

Resolution:

The result is returned from the Show method as type System.Windows.MessageBoxResult so you can just test for the result directly in a conditional statement like:

 
      evaluate type System.Windows.MessageBox::Show(
             "My Text",
             "My Caption",
              type System.Windows.MessageBoxButton::YesNo
              type System.Windows.MessageBoxImage::Question
              type System.Windows.MessageBoxResult::Yes
              type System.Windows.MessageBoxOptions::RightAlign)
          when type MessageBoxResult::Yes
               perform yes-processing
            when type MessageBoxResult::No
               perform no-processing
       end-evaluate

Problem:

Customer has a WPF application that has a main form that launches other forms.
When one of these other forms is closed they would like to be able to pass some data entered in the form back to the main form.

How can this be accomplished?

Resolution:

This can be done by creating a method within the main form that will be invoked automatically when one of the other forms is closed by attaching the method to the FormClosed event handler for the child forms.

If the data that was entered in the child forms is stored as a property then that data can be read from within the main forms method that is attached.

Here is an example that has a main program that displays a new form using the Show method and then attaches a local method to the FormClosed event so that it will be invokes automatically when the form is closed. That method is then used to read the property set in the child form and populate a TextBox on the main form with the text.

Example:

Here is the code for Window 1 which is in a WPF application project:

       class-id WPFWindows1.Window1 is partial
                 inherits type System.Windows.Window.

       working-storage section.
       01 mywindow2 type WPFWindows2.Window2.
       method-id NEW.
       procedure division.
           invoke self::InitializeComponent()
           goback.
       end method.

       method-id Window_Closed2.
       procedure division using by value sender as object e as type System.EventArgs.
          set self::txtParam::Text to mywindow2::myfield
       end method.

       method-id Button_Click.
       procedure division using by value sender as object e as type System.Windows.RoutedEventArgs.
           set mywindow2 to new WPFWindows2.Window2
          *> use this syntax in V2.1 
           invoke mywindow2::add_Closed(new EventHandler(self::Window_Closed2))
          *> use this syntax in V2.2
           *>attach method self::Window_Closed2 to mywindow2::Closed
           invoke mywindow2::Show
       end method.

       end class.

and the code for Windows 2 which is in a WPF library:

       class-id WPFWindows2.Window2 is partial
                 inherits type System.Windows.Window.

       working-storage section.
       01 myfield  string property.
       method-id NEW.
       procedure division.
           invoke self::InitializeComponent()
           set self::txtParam::Text to "Enter Name"
           goback.
       end method.

       method-id Button_Click.
       procedure division using by value sender as object e as type System.Windows.RoutedEventArgs.
           set myfield to self::txtParam::Text
           invoke self::Close
       end method.

       end class.

Problem:

Customer is looking for a way to do a text search for a COBOL identifier and include all programs within a Visual Studio project or solution.

Is this possible?

Resolution:

Use the Find In Files option to search for a text string within your project or solution or elsewhere.

Under Edit-->Find and Replace-->Find In Files

Select the desired location to search, such as Project or Solution in the Look in dropdown list along with any other options like case matching, etc.

Problem:

Customer is migrating his application from Net Express to Visual COBOL. The application is a mixture of COBOL and C programs where there is a main entry point WinMain that resides within a C library.

Under Net Express they used a makefile to call the system linker directly in order to link this so that the C WinMain would be the main entry point and the COBOL objects would be alternate entry points.

The customer now wishes to compile and link this in the same manner but using a Visual COBOL project to do the build instead of a makefile.

The program builds and links OK but it is not picking up the WinMain in the C .LIB as the main entry point so it does not start correctly.

When they try to specify WinMain as the entry point on the COBOL Link tab of the project properties it gives them an error that this entry point cannot be found.

How can they use this link scenario from within a Visual COBOL project?

Resolution:

Add the following to the additional directives on the bottom of the COBOL Link Property page.

-WL/entry:WinMain@16

This tells the linker to force the main entry point to be the name specified so that it will search all .LIBs for that name.

Problem:

Customer has a Windows Forms application that uses a form with a number of TextBox controls on it.
When they press "tab" or click the mouse on another control, the data is processed. When they press "enter" nothing happens. Customer asks: How can I have the enter key behave like the tab key?

Resolution:

In the properties for the form set the KeyPreview property to true.

Create a KeyDown event handler for the form and place the following code into it:

       method-id Form1_KeyDown final private.
       procedure division using by value sender as object e as type System.Windows.Forms.KeyEventArgs.
           
           if e::KeyCode = type System.Windows.Forms.Keys::Return
              set e::Handled to true
              set e::SuppressKeyPress to true
              invoke type SendKeys::Send("{TAB}")   
           end-if.
           
       end method.

Problem:

Customer has an application that is reading an indexed file which contains sveral fields defined as PIC X.
These fields may contain ANSI characters like the German ä/ö/ü/ß"...

After reading a record and moving a field containing these characters to a TextBox control the characters are not being displayed properly.

The move statement looks like:

      move field1 to textBox1::Text

How can these characters be displayed correctly in the textbox control?

Resolution:

If the field that you are reading in is defined as PIC X then it will be read as ANSI data.

The TextBox::Text property uses Unicode as do all .NET strings so the data needs to be converted before it is displayed.

The following example will work where my-ansi-field would contain German characters read from a file:

   01 my-ansi-field pic x(5).
   01 myarray type Byte[].
...
        set myarray to my-ansi-field
        set self::textBox1::Text to type System.Text.Encoding::Default::GetString(myarray)

Problem:

Eclipse crashes when editing remote cobol source files outside of the IDE

Resolution:

Starting eclipse.exe with the -clean option will resolve this issue.

Certain cache/settings can cause this problem. For example, files may not be cached correctly if a remote connection failed. Clearing and resetting the cache resolves this problem.

Problem

How to configure Visual COBOL for Eclipse for debugging when the source is located on a different machine to the code which is being executed.

Resolution

First create a remote project for Machine A.

For this demonstration this project contains the source for tictac.cbl with some of the code replaced by procedural copybooks.

Next, build the project to GNT. FTP the generated GNT and IDY files to the second system (Machine B) and delete the GNT and IDY files from Machine A.

Now create a second remote project for Machine B, pointing to the location of the GNT and IDY files.

In Project Properties, Project References selecte the remote Machine A project.

Now build this second project.

You now have two projects on two different machines.  Source is on Machine A with the executable GNT and debug information IDY files on Machine B.

To debug you must create a debug launch perspective for a COBOL Application, de-select “program is part of a project build configuration” (under Main Program) and browse to the GNT file on Machine B.

In the Source tab add the remote COBOL Project on Machine A using Add, COBOL Project then select the Machine A project. The source tab should now look like this:

Select Apply followed by debug and the debug session will begin:

Please see the attached FAQ.

Pre-Authorized License FAQs V1.1 (Customer).pdf

Problem

SQLSTATE=42704 error seen when running a query in OpenESQL Assistant against DB2 ODBC DSN in Visual COBOL for Visual Studio

Resolution

When the DB2 ODBC connection is setup, you must not define a default user and password.

If you take those defaults out the connection will be made successfuly.

This issue is related to how the preprocessor checks for the objects, and changing the above resolves this.

Problem:

When building a Cobol program using Net Express 5.1 - File I-O error: <filename>.idy - seen in build

Resolution:

Some files needed for building the Net Express project are missing or not found.

A repair of the Net Express 5.1 Product via Windows > Control Panel resolves the issue.

Problem:

Cannot connect to the Micro Focus License Server after changing ip-address.

Massage received states "Cannot connect to the License Server" when starting NetExpress 5.1.

Resolution:

If the local admin password has been changed, it must also be changed in the security properties for the IIS Web Server which the License Server uses.
Changing the password in the security properties will allow a connection the License Server again.